19 IFA=0THENA=1:LOAD"RHEA MSC",8,1
29 POKE808,225:POKE53280,11:POKE53281,11:PRINT"[147][142]":X=-1:X=-1:Z=11:GOSUB39:X=-1:Z=9:GOSUB39:X=-1:Z=6:GOSUB39:X=-1:Z=5:GOSUB39:X=-1:Z=3:GOSUB39:X=-1:Z=0:GOSUB39:GOSUB59:GOTO69
39 X=X+1:GOSUB59:PRINT""TAB(X)"[180]":PRINTTAB(X)"[180]":PRINTTAB(X)"[180]":GOSUB59:PRINT""TAB(X)"[212]":PRINTTAB(X)"[212]":PRINTTAB(X)"[212]":GOSUB59:PRINT""TAB(X)"[194]":PRINTTAB(X)"[194]":PRINTTAB(X)"[194]":GOSUB59:IFX=ZTHENRETURN
49 PRINT""TAB(X)"[200]":PRINTTAB(X)"[200]":PRINTTAB(X)"[200]":GOSUB59:PRINT""TAB(X)"[217]":PRINTTAB(X)"[217]":PRINTTAB(X)"[217]":GOSUB59:PRINT""TAB(X)"[170]":PRINTTAB(X)"[170]":PRINTTAB(X)"[170]":PRINT""TAB(X)" ":PRINTTAB(X)" ":PRINTTAB(X)" ":GOTO39
59 FORXE=1TO10:NEXTXE:RETURN
69 PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[198]":GOSUB59:PRINT"[210]":GOSUB59:PRINT"[175]":GOSUB59:PRINT" ":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59
79 PRINT"[198]":GOSUB59:PRINT"[210]":GOSUB59:PRINT"[175]":GOSUB59:PRINT" ":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[198]":GOSUB59:PRINT"[210]":GOSUB59:PRINT"[175]":GOSUB59:PRINT" ":GOSUB59:PRINT"[183]":GOSUB59
89 PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[198]":GOSUB59:PRINT"[210]":GOSUB59:PRINT"[175]":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[198]":GOSUB59:PRINT"[210]":GOSUB59:PRINT"[175]":GOSUB59
99 PRINT" ":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[198]":GOSUB59:PRINT"[210]":GOSUB59:PRINT"[175]":GOSUB59
109 PRINT" ":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[197]":GOSUB59:PRINT"[196]":GOSUB59:PRINT"[195]":GOSUB59:PRINT"[183]":GOSUB59:PRINT"[205]":PRINT"[206]":PRINT"[205]":POKE56325,0:PRINT"","(W) 1997 BY JTR":GOSUB1009:POKE56325,56:FORX=1TO500:NEXT
119 PRINT"(A)NLEITUNG":PRINT"(S)PIEL BEGINNEN":PRINT"WIE LAUTET DEINE WAHL?";
129 GETA$:IFA$=""THEN129
139 IFA$="A"THEN169
149 IFA$="S"THEN249
159 GOTO129
169 PRINT"[147]            RHEA - ANLEITUNG            ":PRINT"IM JAHRE 2367 BEGANN DER KRIEG ZWISCHEN":PRINT"DER ERDE UND IHREN EHEMALIGEN INTERPLA-":PRINT"NETARISCHEN KOLONIEN AUF DEN SATURNTRA-":PRINT"BANTEN. AUF RHEA, TITAN UND JAPETUS WUR-";
179 PRINT"DEN NAEMLICH TIEF IM GESTEIN GROSSE MEN-";:PRINT"GEN AN GEBUNDENEN SAUERSTOFF ENTDECKT.":PRINT"DIE ERDE, DIE NUR NOCH KNAPPE RESSOURCEN";:PRINT"VON DER DOCH SO WICHTIGEN ATEMLUFT BE-":PRINT"SASS, VERSUCHTE MIT ALLEN MITTELN HERR"
189 PRINT"UEBER DIE DREI ABTRUENNIGEN SATELLITEN"
190 PRINT"ZU WERDEN. DIESER KRIEG ENTSCHIED SICH"
191 PRINT"JEDOCH ZUGUNSTEN DER VERTEIDIGER."
192 PRINT"RHEA, TITAN UND JAPETUS GRUENDETEN EINE"
193 PRINT"KONFOEDERATION, DIE DAS GESAMTE SATURN-"
199 PRINT"AREAL EINBESCHLOSS. 18 JAHRE SPAETER GE-";:PRINT"SCHAH DAS UNGLUECK: EIN METEOR SCHLUG":PRINT"AUF RHEA EIN, ZERSTOERTE EINEN GROSSTEIL";:PRINT"DER FABRIKANLAGEN UND BRACHTE TAUSENDEN":PRINT"VON KOLONIALISTEN DEN TOD.":GOSUB979
209 PRINT"[147]            RHEA - ANLEITUNG           [146]":PRINT"SO WURDE DER EINST REICHE KONFOEDERA-":PRINT"TIONSPARTNER ZU EINEM ORT DER ARMUT UND":PRINT"ANARCHIE. DA EIN WIRTSCHAFTLICHER UNTER-";:PRINT"GANG RHEAS SICH SCHAEDLICH AUF DIE GE-"
219 PRINT"SAMTE SATURN-KONFOEDERATION AUSWIRKEN":PRINT"WUERDE, SCHICKT MAN DICH - EINEN GEBUER-";:PRINT"TIGEN TITANIER - ZU RHEA, DAMIT DU ALS":PRINT"PRAESIDENT DEN WIEDERAUFBAU DER PRODUK-":PRINT"TIONSANLAGEN ORGANISIERST.":PRINT"MAN GEWAEHRT DIR ZEHN PERIODEN (DAS SIND";
229 PRINT"CA. VIEREINHALB IRDISCHE JAHRE) AN ZEIT,";:PRINT"UM AUS RHEA WIEDER DEN WICHTIGEN WIRT-":PRINT"SCHAFTSFAKTOR DER KONFOEDERATION ZU MA-":PRINT"CHEN, DER ER EINMAL WAR.":PRINT"SOLLTEST DU ES IN DER ZEIT NICHT SCHAF-":PRINT"FEN, ODER SOLLTEN KONTRAREVOLUTIONAERE"
239 PRINT"REBELLEN DEINE HERRSCHAFT STUERZEN, SO":PRINT"WIRD MAN EINEN NEUEN PRAESIDENTEN WAEH-":PRINT"LEN UND DICH WIEDER NACH TITAN SCHICKEN.":GOSUB979
249 SYS32768:POKE53280,0:POKE53281,0
259 PRINT"[147][146]EIN NEUES SPIEL BEGINNT...":FORX=1TO1500:NEXT:L1$="[213][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][178][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][201]":L2$="[171][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][219][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][179]":L3$="[194]                    [194]                 [194]"
269 L4$="[202][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][177][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][203]":P=5000:M=2000000:F=5000:T=10:Z$=CHR$(34):GOSUB859:T=11:GOTO289
279 GOSUB859
289 IFT<2THEN769
299 PRINT"[147]     DER BEGINN EINER NEUEN PERIODE     [146]":T=T-1:X=-1:PRINT"WIEVIEL VON DEM BUDGET FUEHREN SIE IHREM";
309 INPUT"[145]EIGENEM VERMOEGEN ZU";X:IFX<0THEN309
319 M=M-X:R=R+X:PRINT"IHR PRIVATVERMOEGEN BELAEUFT SICH JETZT ALSO AUF"R"CREDITS.":GOSUB979:IFR>=((RND(8)*3)-1)*MTHENGOSUB899
329 PRINT"[147]       BERICHT AUS DEN WERKHALLEN       ":A=INT(RND(3)*3)+1:IFA=1THENPRINT"ES WURDEN MEHR SAUERSTOFFEINHEITEN HER-"
339 IFA=1THENPRINT"GESTELLT ALS ERWARTET.":GOTO359
349 PRINT"DIE MENGE DER HERGESTELLTEN SAUERSTOFF-":PRINT"EINHEITEN IST ZUFRIEDENSTELLEND."
359 IFA=1THENF=F+2000:P=P+5000:M=M+10000
369 IFA=2THENX=-1:PRINT"ES WERDEN DRINGEND RAUMTRANSPORTER BE-"
379 IFA=2THENPRINT"NOETIGT. KOSTEN: 10000 CREDITS PRO EIN-"
389 IFA=2THENPRINT"HEIT. WIEVIELE TRANSPORTER WOLLEN SIE"
399 IFA=2THENINPUT"[145]ANSCHAFFEN";X:F=500*X:IFX<0THEN399
409 IFA=2ANDX>0THENM=M-(X*10000)
419 IFA=3THENPRINT"DIE REBELLEN SABOTIEREN IHRE ANLAGEN.":GOSUB689
429 IFP<1000THENGOSUB899
439 GOSUB979:PRINT"[147]":GOSUB859:PRINT"[147]          STAND DER RESSOURCEN          ":X=INT(RND(3)*3)+1:IFX=1THENGOSUB509
449 IFX=2THENGOSUB519
459 IFX=3THENGOSUB549
469 GOSUB979:GOTO279
479 PRINT"[147]      SIE HABEN DAS SPIEL GEWONNEN      ":PRINT"DIE SAUERSTOFFPRODUKTION IST ERGIEBIGER":PRINT"DENN JE. SIE SIND VON TITAN NICHT MEHR":PRINT"ABHAENGIG. SIE VERSORGEN NUN ENCELADUS,":PRINT"THETYS UND DIONE MIT IHREN ROHSTOFFEN."
489 PRINT"SIE HABEN RHEAS WIRTSCHAFTSKAPITAL SOWIE";:PRINT"IHR EIGENES ENORM GESTEIGERT. AUSSERDEM":PRINT"HABEN SIE DIE URSPRUENGLICHE BEVOELKE-":PRINT"RUNGSDICHTE WIEDER HERGESTELLT.":PRINT"OB DIESES ERFOLGES ERNENNT MAN SIE ZUM"
499 PRINT"PRAESIDENTEN AUF LEBENSZEIT. HERZLICHEN":PRINT"GLUECKWUNSCH!":GOSUB979:RUN259
509 PRINT"ES IST NOCH GENUEGEND SAUERSTOFF VORHAN-";:PRINT"DEN.":P=P+2000:M=M+100000:RETURN
519 U1=INT((5*(10^5)*RND(1))+5*(10^5)):PRINT"ES WIRD EIN UEBERSCHUSS AN SAUERSTOFF":PRINT"PRODUZIERT, DEN SIE NACH DIONE EXPORTIE-";:PRINT"REN. DAS BRINGT IHNEN"U1"CREDITS":X=-1:PRINT"EIN. WIEVIEL PROZENT DAVON WOLLEN SIE"
529 INPUT"[145]SICH ANEIGNEN";X:IFX<0ORX>100THEN529
539 M=M+INT(U1-(U1*X/100)):R=R+INT(U1*X/100):RETURN
549 PRINT"EIN LECK IM TANKLAGER LIESS FAST DEN GE-";:PRINT"SAMTEN SAUERSTOFF ENTWEICHEN. WAS GEDEN-";:PRINT"KEN SIE ZU TUN?":PRINT"(A) DIE REPARATUR FINANZIEREN":PRINT"(B) VERSUCHEN, MIT DEN RESERVEN AUSZU-":PRINT"    KOMMEN":PRINT"(C) SAUERSTOFF VON TITAN IMPORTIEREN"
559 GETC$:IFC$=""THEN559
569 IFC$<>"A"ANDC$<>"B"ANDC$<>"C"THEN559
579 IFC$="A"THENM=M-INT(20000*RND(8)):P=P-INT(100*RND(8))
589 IFC$="B"THENP=P-INT(2000*RND(8)):M=M-INT(RND(8)*10000)
599 IFC$="C"THENM=M-INT(RND(3)*400000)
609 IFM<0THENM=0:GOSUB899
619 IFP<100THENP=100
629 RETURN
639 M=M-INT((10^5)*RND(1))+10^5:IFI>=P*.8THENPRINT"SIE SIND GESTUERZT WORDEN. SIE HABEN DAS";
649 IFI>=P*.8THENPRINT"SPIEL LEIDER VERLOREN.":GOSUB979:RUN259
659 IFRND(8)<.7THENPRINT"SIE BEHAUPTEN IHRE MACHT.":GOSUB979:RETURN
669 PRINT"AUFGRUND IHRER TYRANNISCHEN REGIERUNG":PRINT"WERDEN SIE VON RHEA VERBANNT.":GOSUB979:RUN259:INPUTX:IFX=0THENGOSUB899
679 M=M-X*10000:RETURN
689 PRINT"WAS GEDENKEN SIE ZU TUN?":PRINT"(A) DIE SICHERHEITSKRAEFTE VERSTAERKEN":PRINT"(B) DEN SAUERSTOFF FUER VERDAECHTIGE":PRINT"    RATIONIEREN":PRINT"(C) DIE ANGELEGENHEIT IGNORIEREN"
699 GETA$:IFA$=""THEN699
709 IFA$<>"A"ANDA$<>"B"ANDA$<>"C"THEN699
719 IFA$="A"THENI=I-INT(1000*RND(2)):M=M-INT((10^4*RND(1))+10^4):IFI<1THENI=0
729 IFA$="C"THENF=F-INT(RND(4)*3000)
739 IFA$="B"THENI=I+INT(500*RND(7))
749 IFF<1THENF=0
759 RETURN
769 PRINT"[147]    IHRE ZEIT IST LEIDER ABGELAUFEN!    ":PRINT"SIE KONNTEN IHR VOLK LEIDER NICHT ZU-":PRINT"FRIEDENSTELLEN. ES WIRD EIN NEUER PRAE-":PRINT"SIDENT GEWAEHLT.":GOSUB979:RUN259
779 PRINT"[147]     DER SAUERSTOFF GEHT ZUR NEIGE!     ":PRINT"WAS SOLLEN DEINE KOLONIALISTEN JETZT":PRINT"BLOSS TUN?":PRINT"(A) DIE LUFT ANHALTEN":PRINT"(B) DU IMPORTIERST SAUERSTOFF VON RHEA":PRINT"(C) DU STEIGERST DIE SAUERSTOFFPRODUK-":PRINT"    TION"
789 GETB$:IFB$=""THEN789
799 IFB$<>"A"ANDB$<>"B"ANDB$<>"C"THEN789
809 IFB$="A"THENGOSUB899
819 IFB$="B"THENM=M-P*250
829 IFB$="C"THENM=M-P*200:P=INT(P*.95)
839 IFM<0THENM=0:GOSUB899
849 RETURN
859 PRINT"[147]   DER LAGEBERICHT FUER DIESE PERIODE   [146]":PRINT""L1$;:FORX5=1TO5:PRINTL3$;L2$;:NEXT:PRINTL3$;L4$:FORX5=1TO150:NEXT:PRINT"KOLONIALISTEN",""P:PRINT"BUDGET",,""M"CR.":PRINT"EIGENES VERMOEGEN",""R"CR.":PRINT"SAUERSTOFFEINHEITEN"F
869 PRINT"REGIERUNGSZEIT NOCH"T"PERIODEN":PRINT"REBELLEN",,""I:GOSUB979:IFP=>8000ANDM=>8000000ANDF>8000ANDR>1500000THEN479
879 IFF<1THEN779
889 RETURN
899 PRINT"[147]      EINE REBELLION BAHNT SICH AN      ":PRINT"WAS WOLLEN SIE UNTERNEHMEN?":PRINT"(A) RHEA VERLASSEN UND INS EXIL GEHEN":PRINT"(B) DEN AUFSAESSIGEN IHR PRIVATES VER-":PRINT"    MOEGEN UEBERLASSEN":PRINT"(C) WIDERSTAND LEISTEN"
909 GETD$:IFD$=""THEN909
919 IFD$<>"A"ANDD$<>"B"ANDD$<>"C"THEN909
929 IFD$="A"THEN969
939 IFD$="B"THENM=M+R:R=0
949 IFD$="C"THENGOSUB639
959 I=I+INT(RND(8)*P/5):RETURN
969 PRINT"SIE KOENNEN ENTKOMMEN, HABEN DAS SPIEL  JEDOCH VERLOREN.":GOSUB979:RUN259
979 PRINT"":PRINT"        BITTE LEERTASTE DRUECKEN       ";:POKE2023,160
989 GETAO$:IFAO$<>" "THEN989
999 RETURN
1009 PRINT"DIESES SPIEL WIRD VERTRIEBEN VON":PRINT"B-SOFT":PRINT"MIKE WITSCHI UND MAIK HOLSTEIN":PRINT"HENNINGSTR. 13":PRINT"21337 LUENEBURG":RETURN